Nightshift Sound & Vision/Nightshift - Sound & Vision.iso/gfxmanager/install_gfxmanager

Text File | 1995-10-17 | 6KB | 207 lines

; $VER: Install.script V1.1 (11.8.95)
; ⌐ 1995 by Thomas Treder / Nightshift.
; This is the Amiga-Installer Script for GFXManager


;***** Set Language

(set selectlang (askchoice
                   (prompt "")
                   (help @askchoice-help)
                   (choices "Deutsche Installation" "English Installation")
                   (default 0)
                 )
)

(if (= selectlang 0)
 (set @language "deutsch")
 (set @language "english")
)

(if (= @language "deutsch")

  (
    (set MSG_wrong_OS        (cat "Sie ben÷tigen mindestens OS V2.04 \nzum starten des GFXManager !\n\n"
                                  "GFXManager wird auf Ihrem System nicht laufen !"))
    (set MSG_Installing           "Installiere jetzt GFXManager !")
    (set MSG_InstallPatch         "Installiere Amiga OS3.1 - Patch !")
    (set MSG_SelectPath           "WΣhlen Sie bitte das Zielverzeichnis fⁿr GFXManager \n\(Das Verzeichnis `GFXManager` wird autom. erzeugt !\)")
    (set MSG_EditStartup          "Es werden einige ben÷tigte Anweisungen in die Datei \"s:user-startup\" eingetragen.")
    (set MSG_InstallLibs          "Installiere IXEmul.Library ...")
    (set MSG_InstallSetpatch      "Installing Setpatch V.40.14 ...")
    (set MSG_InstallFonts         "Installiere ZeichensΣtze ...")
    (set MSG_ChoiceTitle          "Verfⁿgt Ihr Rechner ⁿber einen Flie▀kommaprozessor ?")
    (set MSG_Choice               "Keine FPU")
    (set MSG_DeleteOld            "L÷sche alte Dateien ...")
  )
  (
    (set MSG_wrong_OS        (cat "You need at least OS V2.04 to run GFXManager !\n\n"
                                  "GFXManager will not run with your system configuration !"))
    (set MSG_Installing           "Installing GFXManager now !")
    (set MSG_InstallPatch         "Installing Amiga OS3.1 - Patch !")
    (set MSG_SelectPath           "Select path to install GFXManager to \nThe drawer `GFXManager` will be autom. created !")
    (set MSG_EditStartup          "Some required commands will be added to your \"s:user-startup\" file.")
    (set MSG_InstallLibs          "Installing IXEmul.Library ...")
    (set MSG_InstallSetpatch      "Installing Setpatch V.40.14 ...")
    (set MSG_InstallFonts         "Installing Fonts ...")
    (set MSG_ChoiceTitle          "Is your Computer equiped with a FloatingPointUnit ?")
    (set MSG_Choice               "NO FPU")
    (set MSG_DeleteOld            "Deleting old files ...")
  )
)

(set OS_VER (/ (getversion) 65536) )

(if(< OS_VER 37)
  (abort MSG_wrong_OS)
)

;***** Copy Files
(complete 0)

(copyfiles
  (prompt MSG_Installing)
  (help @copyfiles-help)
  (source "")
  (set pmcomdir
              (askdir
                     (prompt MSG_SelectPath)
                     (help @askdir-help)
                     (newpath)
                     (default "SYS:")
              )
  )
  (if (patmatch "#?GFXManager" pmcomdir)
      (
          (set Destination pmcomdir)
      )
      (
          (set Destination (tackon pmcomdir "GFXManager"))
      )
   )
  (dest Destination)
  (pattern "~(Font#?|Libs#?|Install#?)")
  (optional ("nofail") ("askuser"))
  (infos)
  (confirm)
)

;***** Install Amiga OS3.1-Patch
(complete 40)

(if(= OS_VER 40)
  (copyfiles
    (prompt MSG_InstallPatch)
    (help @copyfiles-help)
    (source "MathIEEESingBasPatch/MathIEEESingBasPatch")
    (dest "C:")
    (optional ("nofail") ("askuser"))
    (confirm)
  )
  (run "MathIEEESingBasPatch/MathIEEESingBasPatch")
)

;***** Rename needed Files
(complete 50)

(set Path (tackon pmcomdir "GFXManager/bin/"))
(if (exists (tackon Path "djpeg") (noreq))
    (
     (delete (tackon Path "djpeg") (safe) (prompt MSG_DeleteOld) (help @delete-help))
    )
)
(if (exists (tackon Path "ppm2AGA") (noreq))
    (
     (delete (tackon Path "ppm2AGA") (safe) (prompt MSG_DeleteOld) (help @delete-help))
    )
)
(set selectFPU (askchoice
                  (prompt MSG_ChoiceTitle)
                  (help @askchoice-help)
                  (choices "FPU" MSG_Choice)
                  (default 1)
               )
)
(if (> (database "cpu") "68010")
    (
     (if (= selectFPU 0)
         (
             (rename (tackon Path "djpeg.020881") (tackon Path "djpeg") (safe))
         )
         (
             (rename (tackon Path "djpeg.000") (tackon Path "djpeg") (safe))
         )
     )
     (rename (tackon Path "ppm2AGA.020") (tackon Path "ppm2AGA") (safe))
    )
    (
     (rename (tackon Path "djpeg.000") (tackon Path "djpeg") (safe))
     (rename (tackon Path "ppm2AGA.000") (tackon Path "ppm2AGA") (safe))
    )
)

;***** Install Fonts
(complete 65)

(copyfiles
  (prompt MSG_InstallFonts)
  (help @copyfiles-help)
  (source "Fonts")
  (dest "Fonts:")
  (all)
  (optional ("nofail") ("askuser"))
  (confirm)
)
(set @default-dest (expandpath pmcomdir))

;***** Copy Library
(complete 70)

(copylib
        (prompt MSG_InstallLibs)
        (help @copylib-help)
        (source "Libs/ixemul.library")
        (dest "Libs:")
        (optional ("nofail") ("askuser"))
)

;***** Copy Library
(complete 75)

(copylib
        (prompt MSG_InstallSetpatch)
        (source "Setpatch/Setpatch")
        (dest "C:")
        (optional ("nofail") ("askuser"))
        (help @copylib-help)
)

;***** Edit Startup-Sequence
(complete 90)

(startup "GFXManager"
        (prompt MSG_EditStartup)
        (help @startup-help)
        (if(= OS_VER 40)
             (command "if exists C:MathIEEESingBasPatch\n  C:MathIEEESingBasPatch\nendif\n")
        )
        (command "if exists \"" Destination "\"\n")
        (command "   assign >NIL: GFXManager: \"" Destination "\"\n")
        (command "   assign >NIL: GMData: GFXManager:GMData\n")
        (command "   if exists GFXManager:bin\n")
        (command "      path >NIL: GFXManager:bin add\n")
        (command "      assign >NIL: C: GFXManager:bin add\n")
        (command "   endif\n")
        (command "endif")
)

(makeassign "GFXManager" Destination (safe))
(makeassign "GMData" "GFXManager:GMData" (safe))
(run "assign >NIL: C: GFXManager:bin add")
(run "path >NIL: GFXManager:bin add")

;***** Finished
(complete 100)